ce/main.ml

open Printf

exception Reset_line (* used to indicate ^C is pressed *)

let version = "%%VERSION%%"

let error_to_string e =
  try raise e with
  | Lex.Token_not_found -> sprintf "invalid token"
  | Parser.Expected t -> sprintf "expected %s" t
  | Parser.Unexpected_token t -> sprintf "unexpected token \"%s\"" t
  | Ast.Invalid_type t -> sprintf "invalid type %s" (Ast.Type.to_string t)
  | Eval.No_such_variable v -> sprintf "no such variable %s" v
  | Failure f -> sprintf "error on %s" f
  | Division_by_zero -> "cannot divide by zero"
  | _ -> raise e

let print_error e =
  printf "error: %s\n" @@ error_to_string e

(* read-eval-print *) 
let rep ans : unit =
  printf "> ";
  let line = read_line () in
  if line = "quit" then raise Exit;
  let v =
    line
    |> Lex.tokenize
    |> Parser.parse
    |> Eval.eval !ans
  in
  match v with
  | Nop -> ()
  | _ ->
    ans := v;
    printf "%s\n" @@ Ast.Value.to_string v

let init_repl () =
  let sigintf _ = raise Reset_line in
  Sys.(set_signal sigint (Signal_handle sigintf))

(* simple REPL with error handling *)
let rec repl ans : unit =
  try rep ans; repl ans with
  | Exit | End_of_file -> ()
  | Reset_line -> printf "\n"; repl ans
  | e -> print_error e; repl ans

let () =
  let ans = ref @@ Ast.Value.Int 0 in
  init_repl ();
  printf "Configurable Evaluator %s\n" version; (* banner *)
  repl ans