open Printf

exception Reset_line (* used to indicate ^C is pressed *)

let version = "%%VERSION%%"

let error_to_string e =
  try raise e with
  | Lex.Token_not_found -> sprintf "invalid token"
  | Parser.Expected t -> sprintf "expected %s" t
  | Parser.Unexpected_token t -> sprintf "unexpected token \"%s\"" t
  | Ast.Invalid_type t -> sprintf "invalid type %s" (Ast.Type.to_string t)
  | Failure f -> sprintf "error on %s" f
  | Division_by_zero -> "cannot divide by zero"
  | _ -> raise e

let print_error e =
  printf "error: %s\n" @@ error_to_string e

(* read-eval-print *) 
let rep () : unit =
  printf "> ";
  let line = read_line () in
  if line = "quit" then raise Exit;
  let ans =
    line
    |> Lex.tokenize
    |> Parser.parse
    |> Eval.eval
  in
  match ans with
  | Nop -> ()
  | _ -> printf "%s\n" @@ Ast.Value.to_string ans

let init_repl () =
  let sigintf _ = raise Reset_line in
  Sys.(set_signal sigint (Signal_handle sigintf))

(* simple REPL with error handling *)
let rec repl () : unit =
  try rep (); repl () with
  | Exit | End_of_file -> ()
  | Reset_line -> printf "\n"; repl ()
  | e -> print_error e; repl ()

let () =
  init_repl ();
  printf "Configurable Evaluator %s\n" version; (* banner *)
  repl ()